Table of Contents        Previous topic       Next topic       

C COMPILER->Compiler Support Files->Startup Module

The startup module in the LIB68020.LIB library has been created from the assembler code shown in the following listing.  This assembler code is supplied in file STARTUP.ASM and must be modified to suit the target system and then added to the run time library LIB68020.LIB.

If console i/o is required then putch() and getch() routines must also be written specifically for the target system.  All other console i/o functions call these two target specific functions and so once these are written, then all of these will automatically work correctly too.  Versions are included in the library (and are described later) but these must be re-written for your particular target board.

The following listing shows the startup routine that has been included in the library but this must be modified to suit your target board.

*    Example startup Routine

    xref    _main,__initdata,__HP
    xdef    __cstart,_exit

    section    __STACK,data,high    * Linker places this at                * highest available ram location
    ds.w    1        * 1 word minimum to create section

    section __HEAP,data,postpone    * Linker places this after                * all ram sections except __STACK
    ds.w    1        * 1 word minimum to create section

    org    400600H        * Lowest user ram location
__cstart
    cmp.l    #400600H,a7    * Test supervisor mode (by
                * looking at stack pointer)
    bge.s    skip1        * Skip set user mode if already
                * set

            * In supervisor mode if here
    move    sr,d0        * Get status register
    andi    #$dfff,d0    * Clear S bit in status register
    move    d0,sr        * Set user mode
skip1    movea.l    #__STACK,a7    * Set user stack pointer
    move.l    #__HEAP,__HP    * Initialise heap pointers
    jsr    __initdata
    jsr    _main
_exit
    trap    #11        * Call monitor RENTER command
    dc.w    0        * Re-enter monitor


You should note the following points about this sample startup routine:

• The label __cstart is compulsory.  It is the presence of this externally accessible label that forces the linker to include the startup module in the final program.  (The compiler automatically generates an xref for this label to cause this to happen.).
  

• The subroutine __initdata is included in the library and initialises all of the compiler data space to the required values.  This must be called before main.
  

• The instructions following the _exit label needs to be modified to suit your target system.  
  

• The instructions are in an absolute code segment with the origin set to $400600.  This needs to be modified to suit your target system.  
  

• The sample code has been written for a target board that has an operating system monitor running on it.  To run without such a monitor will require additional code to be added specific to your target system.
  

• A heap provides run time memory through calls to malloc().  This heap is positioned above all other data and builds upwards as memory is allocated.  The stack builds downwards from top of memory.  All of the memory between the bottom of the heap and the top of the stack is therefore available during run time to be used either by both the heap and stack.  
  

• In the above listing, __HP is the heap pointer and A7 is, as usual, the stack pointer.  Segments __HEAP and __STACK are given types postpone and high respectively to force the linker locates them in the correct positions.  
  

• The above startup code initialises __HP and A7 by loading the segment addresses __HEAP and __STACK into them.